SUBROUTINE CAGRFAC
C
C J.T. Armstrong      30 Dec 1990
C
C Adapted from BAGRFAC (R.S. Simon).  This subroutine finds the 
C reduced chi squares for the fit of a model to a binary.
C-----------------------------------------------------------------------

      INCLUDE 'BINFIT.INC'

      REAL*8 CSUM(MXREC), AMPSUM, VSUM

C Amplitude agreement factors.

D     WRITE(OUTC,'(A,F10.5)') ' CAGRFAC going in: TCHISQ = ',TCHISQ
D     WRITE(OUTC,'(A,I4)') ' CAGRFAC going in: NZTOT = ',NZTOT

      AMPSUM = 0.
      DO IG = 1, NFILT
D         WRITE(OUTC,'(A,I2,A,I4)') ' CAGRFAC going in: NZVIS(',IG,
D    1                           ') = ',NZVIS(IG)
          IF (NZVIS(IG) .GT. NVPAR(IG)) THEN
              VSUM = 0.
              DO ID = 1, NDATA
                  IF ( (OBSVIS2(ID,IG) .NE. 2.0)
     1                         .AND. 
     2                 (VISERR(ID,IG)  .NE. 0.0) ) THEN
                      RESID(ID,IG) = OBSVIS2(ID,IG) - VIS2(ID,IG)
                      VSUM   = VSUM + (RESID(ID,IG)/VISERR(ID,IG))**2
D     WRITE(OUTC,'(A,I4,A,I2,A,F6.3,A,F6.3)') 
D    1             ' CAGRFAC:  Scan ',ID,', Filter ',IG,':  V^2 = ',
D    2             VIS2(ID,IG),'; Obs V^2 = ',OBSVIS2(ID,IG)
                  ENDIF
              END DO
              FCHISQ(IG) = VSUM / (NZVIS(IG)-NVPAR(IG))
              AMPSUM = AMPSUM + VSUM
          ELSE
              FCHISQ(IG) = -1.
          ENDIF
      END DO
      IF (NZTOT .GT. NVPARTOT) THEN
          TCHISQ =  AMPSUM / (NZTOT-NVPARTOT)
      ELSE
          TCHISQ = -1.
      END IF
D     WRITE(OUTC,'(A,F10.5)') ' CAGRFAC coming out: TCHISQ = ',TCHISQ

      RETURN
      END