SUBROUTINE FITDIA
C
C  This subroutine was written to make it easier to estimate the
C  diameter of calibration stars from a single night's data.  It
C  outputs the average value of VCAL/VEST for all four channels for
C  one star.  It allows the user to change the assumed diameter
C  until this ratio is close to one for all four channels.  This should
C  not be used to fit diameters to stars, but should provide a quick
C  estimate of the star's diameter for use in SYSVIS.  Remember that
C  QCAL needs a uniform disk diameter (800nm) and applies a correction
C  for wavelength dependent limb darkening.  This subroutine replaces
C  the DIAM command.
C
C    David Mozurkewich    21 April 1991
C
C
      IMPLICIT UNDEFINED (A-Z)
      REAL *4 OLDDIAM, NEWDIAM, NEWVIS(4)
      INTEGER *4 I, J, K, COUNT(4), MASK(4)
      INCLUDE 'VPLOT.INC'
      DATA MASK / 1, 2, 4, 8 /
C-----------------------------------------------------------------------
      WRITE(6,*) ' ENTER STAR NUMBER '
      READ (5,*,END=900) I
      K = 0
      DO J = 1, NSTAR
          IF ( I .EQ. SLIST(J) ) THEN
              K = J
              OLDDIAM = ANGDIA(K)
              WRITE(6,1200) OLDDIAM
              GO TO 200
          END IF
      END DO
      WRITE(6,*) ' STAR IS NOT IN LIST '
      GO TO 900
C-----------------------------------------------------------------------
C Calculate the new estimated visibilities.
  200 CONTINUE
          DO J = 1, 4
              NEWVIS(J) = 0.
              COUNT(J) = 0.
          END DO
          DO I = 1, ISCAN
              IF ( STAR(I) .EQ. SLIST(K) ) THEN
                  DO J = 1, 4
                      IF ( IAND(OKSCAN(I),MASK(J)) .EQ. 0 ) THEN
                          CALL QCAL ( BASE(I), HA(I), DEC(I), WAVE(J),
     $                            ANGDIA(K), VEST(I,J) )
                          VCAL(I,J) = VIS(I,J) / SCAL(I,J)
                          VEST(I,J) = MAX ( VEST(I,J), .001 )
                          NEWVIS(J) = NEWVIS(J) + VCAL(I,J) / VEST(I,J)
                          COUNT(J) = COUNT(J) + 1
                      END IF
                  END DO
              END IF
          END DO
C-----------------------------------------------------------------------
C  Display the results and ask for a new diameter.  Quit when the
C  diameter does not change.
C
          DO J = 1, 4
              IF ( COUNT(J) .GT. 0 ) THEN
                  NEWVIS(J) = NEWVIS(J) / COUNT(J)
              END IF
          END DO
          WRITE(6,1210) NEWVIS
          READ (5,*) NEWDIAM
          IF ( NEWDIAM .EQ. OLDDIAM ) GO TO 900
          ANGDIA(K) = NEWDIAM
          OLDDIAM = ANGDIA(K)
      GO TO 200
C-----------------------------------------------------------------------
  900 CONTINUE
      RETURN
 1200 FORMAT ( '  NEW CALIBRATED VISIBILITIES '
     $        /'      OLD DIAMETER = ', F8.2,
     $        /'  CHAN 1   CHAN 2    CHAN 3    CHAN 4  ')
 1210 FORMAT ( 4F8.2, '  INPUT NEW DIAM = ', $ )
      END