! @(#)file_update.prg	14.1.1.1 (ES0-DMD) 09/16/99 09:27:13
! +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
! 
!  MIDAS procedure 'file_update.prg' to update MIDAS data files
!  for the Portable Midas
!  K. Banse	901108
! 
!  use as  @ file_update file_specs N/O
! 
! +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
! 
DEFINE/PARAM P1 + C "enter file specs for CREATE/CATALOG command: "
DEFINE/PARAM P2 N C "enter N or O for moving to new or old format: "
! 
IF P2(1:1) .EQ. "N" THEN
   IF P1(1:1) .NE. "+" THEN		!old 88OCT Midas commands...
      CREATE/CAT filupda IMA 'P1'
   ELSE
      CREATE/CAT filupda IMA 
   ENDIF
ELSE
   IF P1(1:1) .NE. "+" THEN
      CREATE/ICAT filupda 'P1'
   ELSE
      CREATE/ICAT filupda 
   ENDIF
ENDIF
! 
DEFINE/LOCAL NAX/I/1/1 1
DEFINE/LOCAL TEST/C/1/1 'P2(1:1)'
DEFINE/LOCAL CATAL/I/1/1 0
IF TEST .EQ. "N" THEN
   DEFINE/LOCAL DSTA/D/1/6 0.0 ALL
   DEFINE/LOCAL DSTEP/D/1/6 1.0 ALL
ELSE
   DEFINE/LOCAL RSTA/R/1/6 0.0 ALL
   DEFINE/LOCAL RSTEP/R/1/6 1.0 ALL
ENDIF
! 
CAT_LOOP:
STORE/FRAME IN_A filupda.cat 
NAX = '{IN_A},NAXIS'
! 
IF TEST .EQ. "N" THEN
   COPY/DK 'IN_A' START/R/1/'NAX' DSTA/D/1/'NAX'
   COPY/DK 'IN_A' STEP/R/1/'NAX' DSTEP/D/1/'NAX'
ELSE
   COPY/DK 'IN_A' START/D/1/'NAX' RSTA/R/1/'NAX'
   COPY/DK 'IN_A' STEP/D/1/'NAX' RSTEP/R/1/'NAX'
ENDIF
! 
DELE/DESCR 'IN_A' START
DELE/DESCR 'IN_A' STEP
! 
IF TEST .EQ. "N" THEN
   COPY/KD DSTA/D/1/'NAX' 'IN_A' START/D/1/'NAX' 
   COPY/KD DSTEP/D/1/'NAX' 'IN_A' STEP/D/1/'NAX' 
ELSE
   COPY/KD RSTA/R/1/'NAX' 'IN_A' START/R/1/'NAX' 
   COPY/KD RSTEP/R/1/'NAX' 'IN_A' STEP/R/1/'NAX' 
ENDIF
! 
WRITE/OUT file 'IN_A' processed
GOTO CAT_LOOP