IF (OLD_FILE.NE.FILE_NAME) THEN
    SAY "Please use "SELECT" option before"
    RETURN
ENDIF
define integer ir nfix ibs
define character psf*40 code*20
if do_atm then
   set phase atm
else
   set phase noatm
endif
mask shadow  /ant all
!
! 9. Check the efficiencies
!
SET RF ON 
for kr 1 to 2
  let ir irec[kr]
  if irec[kr].gt.0 then
    set receiver irec[kr]
    if do_external.and.(kr.eq.2) then
      set phase external relative
    else
      set phase internal relative
    endif     
    FIND /PROC CORR /TYPE 'caltype'
    FIND append  /PROC CORR /TYPE O /SOURCE MWC349
    FIND append  /PROC CORR /TYPE O /SOURCE CRL618
! 
! Fix some source fluxes
!
    let nfix 0 
    let ibs 0 
    FOR I 1 TO N_cals
      if fix_flux[i,ir] then
         set flux 'cal_source[i]' in_flux[i,ir] frghz[ir]
         let nfix nfix+1
         say "Using "'cal_source[i]'" as a reference source "
      else
         set flux 'cal_source[i]' *
      endif
      if cal_source[i].eq.band_source then
        let ibs i
      endif
    NEXT
    if nfix.eq.0 then
      say "Using "'band_source'" as a reference source "
      set flux 'band_source' in_flux[ibs,ir] frghz[ir]
      let fix_flux[ibs,ir] YES
    endif
    set band 'cal_band[ir]'
    set sub all
    SOLVE FLUX
    LET JYPK[ir] 0.01*NINT(100*min(1000.,JY_PER_K))
    for i 1 to nant
      let ceff[i,ir] 0.01*NINT(100*JY_TO_KEL[i]|JY_PER_K[i])
    next
    if exist(f_solved) then
      FOR I 1 TO N_cals
        set flux 'cal_source[i]' *
        for j 1 to n_solved
          if (solved[j].eq.cal_source[I]) then
             LET Cal_FLUX[I,ir] max(0,0.001*nint(1000.*f_solved[j]))
          endif
        next
      next
    endif
    say "Fluxes are NOT stored ! "
    set antenna
    set y amplitude
    set amplitude scaled
    plot  /id color
! overlay with phase correction validity histogram
    set amplitude UNSCALED
    set y atm_val
    FIND /PROC CORR /TYPE *
    plot /nodraw
    for i 1 to n_boxes
      let y_data[i] y_data[i]*0.1*y_data_max[i]
    next
    set plot his
    plot same /noframe 2
    set plot point
    say "Efficiency check for receiver " -
      'ir' " (" frghz[ir] " GHz):"  /format a i1 a f5.1 a
    FOR I 1 TO N_cals
      let code "(Read) "
      if fix_flux[i,ir] then
        let code "(Fixed "'0.01*nint(100.*in_flux[i,ir])'")"
      endif
      if (cal_SOURCE[I].eq."CRL618") then
        let code "(Model:"'fhii[1,ir]'")"
      else if (cal_SOURCE[I].eq."MWC349") then
        let code "(Model:"'fhii[2,ir]'")"
      endif
      SAY "Flux of "'Cal_SOURCE[I]' rdi_FLUX[I,ir] 'code'"; found" -
      'Cal_FLUX[I,ir]' " Jy"  /FORMAT A21 F10.2 a25 F10.2 a
    next
    STOP
    LET PSF 'short_file'"-eff-"'IR'".ps" 
    SYS "rm "'psf'
    HARD 'psf'  /DEV EPS color
  endif
next
!
if n_cals.le.0 then
  say "No calibrator was found"
  return
endif
mask shadow  /ant all  /reset
!
SAY "To change the flux scale: update the RF Calibrator fluxes"
SAY "and press EFF again."
!
@ x_calib_save