def char code1*12 code2*12 code3*12 code4*12 
def real f1 f2
DEFINE REAL HOURMIN HOURMAX bl[nbas] loss[nbas] seeing[2] bb bbmax degradation
DEFINE INTEGER BASIS[10] 
LET BASIS 12 13 23 14 24 34 15 25 35 45
define character plotps*40
!
IF (OLD_FILE.NE.FILE_NAME) THEN
    SAY "Please use ""SELECT"" option before"
    RETURN
ENDIF
!
! Global quality
!
DEFINE REAL RF[2,2] AP[2,2] 
DEFINE CHARACTER RF_QUAL*16[2] PHA_QUAL*16[2] AMP_QUAL*16[2]
define integer ir nr
let nr 0
for kr 1 to 2
   let ir irec[kr]
   if irec[kr].gt.0 then
      let nr nr+1
   endif
next
!
LET RF 0
LET AP 0
for kr 1 to 2
   let ir irec[kr]
   if irec[kr].gt.0 then
      IF (CAL_BAND[ir].EQ."LSB") THEN
          FOR I 1 TO NBAS
           FOR J 1 2
             LET RF[J,ir] MAX(RF[J,ir],RF_LSB[J,I,ir])
           NEXT
         NEXT
      ELSE IF (CAL_BAND[ir].EQ."USB") THEN
         FOR I 1 TO NBAS
           FOR J 1 2
             LET RF[J,ir] MAX(RF[J,ir],RF_USB[J,I,ir])
           NEXT
         NEXT
      ELSE
         FOR I 1 TO NBAS
           FOR J 1 2
              LET RF[J,ir] MAX(RF[J,ir],RF_LSB[J,I,ir])
              LET RF[J,ir] MAX(RF[J,ir],RF_USB[J,I,ir])
           NEXT
         NEXT
      ENDIF
      let seeing[ir] 0
      let bbmax 0
      FOR I 1 TO NBAS
        if (ir.eq.2).and.do_self then
          LET AP[1,ir] MAX(AP[1,ir],PHA_ERR[i,1]*frghz[2]|frghz[1])
        else
          LET AP[1,ir] MAX(AP[1,ir],PHA_ERR[i,ir])
        endif
        LET AP[2,ir] MAX(AP[2,ir],AMP_ERR[i,ir])
! bl is the baseline in wavelengths
        let bb SQRT(BASELINE[1,I]^2+BASELINE[2,i]^2+BASELINE[3,i]^2)
        let bb bb*frghz[ir]|0.299792
        let seeing[ir] seeing[ir]+PHA_ERR[i,ir]|pi|bb*sqrt(2*log(2.))*3600.
        let bbmax max(bb,bbmax)
      NEXT  
      let seeing[ir] seeing[ir]|nbas
      IF (RF[1,ir].LT.3.AND.RF[2,ir].LT.2) THEN
        LET  RF_QUAL[ir] "EXCELLENT"
      ELSE IF (RF[1,ir].LT.7.5.AND.RF[2,ir].LT.5) THEN
        LET  RF_QUAL[ir] "Good"
      ELSE IF (RF[1,ir].LT.15.AND.RF[2,ir].LT.10) THEN
        LET  RF_QUAL[ir] "Correct"
      ELSE IF (RF[1,ir].LT.25.AND.RF[2,ir].LT.20) THEN
        LET RF_QUAL[ir] "POOR or Noisy"
      ELSE 
        LET RF_QUAL[ir] "BAD"
      ENDIF
!
      if (ir.eq.1).or.(.not.do_self) then
        let degradation sqrt((seeing[ir]|188000*bbmax)^2+1)-1
        if degradation.lt.0.02 then
          LET PHA_QUAL[ir] "EXCELLENT"
        ELSE IF degradation.lt.0.05 then
          LET PHA_QUAL[ir] "Good"
        ELSE IF degradation.lt.0.20  THEN
          LET PHA_QUAL[ir] "Correct"
        ELSE IF degradation.lt.0.40 THEN
          LET PHA_QUAL[ir] "POOR"
        ELSE 
          LET PHA_QUAL[ir] "BAD"
        ENDIF
      else
        if ap[1,ir].lt.10. then
          LET PHA_QUAL[ir] "EXCELLENT"
        ELSE IF ap[1,ir].lt.20 then
          LET PHA_QUAL[ir] "Good"
        ELSE IF ap[1,ir].lt.35  THEN
          LET PHA_QUAL[ir] "Correct"
        ELSE IF ap[1,ir].lt.50 THEN
          LET PHA_QUAL[ir] "POOR"
        ELSE 
          LET PHA_QUAL[ir] "BAD"
        ENDIF
      endif
      IF (AP[2,ir].LT.5) THEN
        LET AMP_QUAL[ir] "EXCELLENT"
      ELSE IF (AP[2,ir].LT.10) THEN
        LET AMP_QUAL[ir] "Good"
      ELSE IF (AP[2,ir].LT.15) THEN
        LET AMP_QUAL[ir] "Correct"
      ELSE IF (AP[2,ir].LT.25) THEN
        LET AMP_QUAL[ir] "Poor"
      ELSE
        LET AMP_QUAL[ir] "Bad"
      ENDIF
   endif
next

!
! 10. Edit the report
!
SIC PREC SINGLE
! 
! summary file
sic date
SIC OUTPUT 'short_file'".sum"
say -
"---------------------------------------------------------------------------"
SAY "  Summary of data quality for project "'PROJECT'
SAY "  File "'FILE_NAME'
say "  Observed on "'date_observed'" configuration "'telescope'-
" ("'configuration'")"
SAY "  Calibration Report by x_calib on " 'sys_date'
SAY "  Operator(s) :"
SAY "  Astronomer  :"
SAY "  Notes       :"
SAY "  Settings    :"
SAY "  Scan Range              :" 'scan_range[1]' " to "  'scan_range[2]'
SAY "  Use R1 phases for R2    :" 'do_external'
SAY "  Self cal. phases R1->R2 :" 'do_self'
SAY "  Use Phase correction    :" 'do_atm'
SAY "  Minimum Quality         :" 'min_qual'

!
! 10.2 Printing summary
!
for kr 1 to 2
  let ir irec[kr]
  if irec[kr].gt.0 then
    SAY " "
    SAY "  Receiver " 'ir'" - Tuning  "'CAL_BAND[ir]'" :"
    SAY "  --------------------------"
    if (ir.eq.2).and.do_self then
      SAY "      Bandpass "'RF_QUAL[ir]' -
        "  Amplitude "'AMP_QUAL[ir]' "  Phase "'PHA_QUAL[ir]' -
         /format a a a 
    else
      SAY "      Bandpass "'RF_QUAL[ir]' -
        "  Amplitude "'AMP_QUAL[ir]' "  Phase "'PHA_QUAL[ir]' -
        " (Seeing: " seeing[ir] "'')"  /format a a a a f4.2 a
    endif
  endif
next
SAY " "
SAY "  Calibrators  "
SAY "  ===========  "
if (nr.eq.2) then
  if exist(n_cals) then
    if n_cals.gt.0 then
      say "           " frghz[1] " GHz" frghz[2] " GHz"     -
                                          /FORMAT a34 f5.1 a f21.1 a
      say "Fluxes (Jy):" " read" " computed" " read" " computed" -
           /format a20 a15 a12 a15 a12
      FOR I 1 TO N_cals
        let code1 " "
        let code2 " "
        let code3 " "
        let code4 " "
        let f1 rdi_FLUX[I,1]
        let f2 rdi_FLUX[I,2]
        if fix_flux[I,1] then
          let code2 "F"
        endif
        if fix_flux[I,2] then
          let code4 "F"
        endif
        if (cal_SOURCE[I].eq."CRL618") then
          let code1 "M"
          let f1 fhii[1,1]
          let f2 fhii[1,2]
        else if (cal_SOURCE[I].eq."MWC349") then
          let code1 "M"
          let f1 fhii[2,1]
          let f2 fhii[2,2]
        endif
        SAY 'Cal_SOURCE[I]' -
        f1 'code1' Cal_FLUX[I,1] 'code2'-
        f2 'code1' Cal_FLUX[I,2] 'code4'-
                       /FORMAT A20 F15.2  a2 F10.2  a2 F13.2  a2 F10.2  a2 
      next
    else
      say " No calibrators !"
    endif
  else
    say " No calibrators !"
  endif
else if (nr.eq.1) then
  if exist(n_cals) then
    if n_cals.gt.0 then
      let ir irec[1]
      say "                    " frghz[ir] " GHz"      /FORMAT a30 f5.1 a 
      say "Fluxes (Jy):" " read" " computed"  /format a20 a15 a12
      FOR I 1 TO N_cals
        let code1 " "
        let code2 " "
        let f1 rdi_FLUX[I,ir]
        if fix_flux[I,ir] then
          let code2 "F"
        endif
        if (cal_SOURCE[I].eq."CRL618") then
          let code1 "M"
          let f1 fhii[1,ir]
        else if (cal_SOURCE[I].eq."MWC349") then
          let code1 "M"
          let f1 fhii[2,ir]
        endif
        SAY 'Cal_SOURCE[I]' f1 'code1' Cal_FLUX[I,ir] 'code2' -
         /FORMAT A20 F15.2 a2 F10.2  a2 
      next
    else
      say " No calibrators !"
    endif
  else
    say " No calibrators !"
  endif
endif
!
!
SAY "  "
SAY "  Efficiencies "
SAY "  ============ "
if (nr.eq.2) then
  say "Rec. " irec[1] "Rec. " irec[2] "  Corr. eff."  /FORMAT a30 i1 a9 i1 a16
  say
  FOR I 1 TO NANT
    SAY "     Antenna " I " (A" phys_ant[i] ")" JYPK[I,1] JYPK[I,2] - 
    " Jy /K (" CEFF[I,1] CEFF[I,2] ")" -
     /FORMAT A i2 a i1 a F10.1 F10.1 A f5.2 f5.2 a
  NEXT
else if (nr.eq.1) then
  FOR I 1 TO NANT
    SAY "     Antenna " I " (A" phys_ant[i] ")" JYPK[I,ir] -
    " Jy /K (" CEFF[I,1] ")" -
     /FORMAT A i2 a i1 a F10.1 A f5.2 a
  NEXT
endif
!
SAY "  "
SAY "  Observed Source(s)      "
SAY "  ==================      "
FIND /PROC CORR  /TYPE O
if (found.gt.0) then
  LIST /SOURCE
  FOR I 1 TO N_SOURCE
    FIND /SOURCE 'C_SOURCE[I]' /PROC CORR /TYP O
    IF (C_SOURCE[I].NE."W3OH".OR.FOUND.GT.10) THEN
       GET FIRST  /header
       LET HOURMIN 12*HOUR_ANGLE|PI
       GET CX_NUM[FOUND]  /header
       LET HOURMAX 12*HOUR_ANGLE|PI
       SAY 'C_SOURCE[I]' " observed for Hour Angles " HOURMIN " to " HOURMAX -
                                               /FORMAT A12 a F6.1 a F6.1
    ENDIF
  NEXT
else
  say "No project source observed"
endif
SAY "               "
SAY "  RF Bandpass: measured on " 'BAND_SOURCE'
SAY "  ============ "
if (nr.eq.2) then
  say " Rec. " irec[1] " Rec. " irec[2]       /FORMAT a34 i1 a31 i1
  say " Band :" " LSB" " USB" " LSB" " USB"      /FORMAT a11 a13 a16 a16 a16
  say "rms :" "Phase" "Amp." "Phase" "Amp."  "Phase" "Amp." "Phase" "Amp." -
                                          /format a11  a9 a8 a8 a8  a8 a8 a8 a8 
  say " " " (deg.)" "(%)" "(deg.)" "(%)" "(deg.)" "(%) " "(deg.)" "(%) " -
                                          /format a11  a9 a8 a8 a8  a8 a8 a8 a8 
  FOR I 1 TO NBAS
    SAY "Base"  basis[i] " : " -
        RF_LSB[2,I,1] RF_LSB[1,I,1] RF_USB[2,I,1] RF_USB[1,I,1] -
        RF_LSB[2,I,2] RF_LSB[1,I,2] RF_USB[2,I,2] RF_USB[1,I,2] -
         /FORMAT  A6 I3 a F8.1 F8.1 F8.1 F8.1 F8.1 F8.1 F8.1 F8.1 
  NEXT
else if (nr.eq.1) then
  say "Band :" "LSB" "USB"                  /FORMAT a11 a13 a16 
  say "rms :" "Phase" "Amp." "Phase" "Amp."   /format a11  a9 a8 a8 a8
  say " " "(deg.)" "(%)" "(deg.)" "(%)"   /format a11  a9 a8 a8 a8
  FOR I 1 TO NBAS
    SAY "Base"  basis[i] " : " -
         RF_LSB[2,I,ir] RF_LSB[1,I,ir] RF_USB[2,I,ir] RF_USB[1,I,ir] -
          /FORMAT  A6 I3  a F8.1 F8.1 F8.1 F8.1 
  NEXT
endif
!
SAY "                   "
SAY "  Time dependence: "
SAY "  ================ "
if (nr.eq.2) then
  say "Rec. " irec[1] "Rec. " irec[2]  /FORMAT a37 i1 a19 i1
  if .not.do_self then
    say "rms : " "Phase" "Amp." "Phase" "Amp."    -
     /format a25  a8 a8 a12 a8
    say    " " "(deg.)" "(%)" "(deg.)" "(%)"  -
     /format a25  a8 a8 a12 a8
  else
    say "rms : " "Phase" "Amp." "Phase   (self) " "Amp."    -
     /format a25  a8 a8 a19 a8
    say    " " "(deg.)" "(%)" "(deg.)" "(deg.)" "(%)"  -
     /format a25  a8 a8 a9 a9 a8
  endif
  FOR I 1 TO NBAS
    LET BB NINT(SQRT(BASELINE[1,I]^2+BASELINE[2,i]^2+BASELINE[3,i]^2))
    if .not.do_self then
      SAY "Base"  basis[i] " (" BB  " m)   : " -
        PHA_ERR[I,1] AMP_ERR[I,1] PHA_ERR[I,2] AMP_ERR[I,2] -
         /FORMAT  A6 I3 A F6.1 A F8.1 F8.1 F12.1 F8.1  
    else
      SAY "Base"  basis[i] " (" BB  " m)   : " -
        PHA_ERR[I,1] AMP_ERR[I,1] -
        PHA_ERR[I,1]*frghz[2]|frghz[1] "(" PHA_ERR[I,2] ")" AMP_ERR[I,2] -
         /FORMAT  A6 I3 A F6.1 A F8.1 F8.1 F8.1 a5 F4.1 a1 F8.1  
    endif
  NEXT
else if (nr.eq.1) then
  say "rms : " "Phase" "Amp."    /format a25  a8 a8 
  say    " " "(deg.)" "(%)"    /format a25  a8 a8 
  FOR I 1 TO NBAS
    LET BB NINT(SQRT(BASELINE[1,I]^2+BASELINE[2,i]^2+BASELINE[3,i]^2))
    SAY "Base"  basis[i] " (" BB  " m)   : " -
        PHA_ERR[I,ir] AMP_ERR[I,ir]   /FORMAT  A6 I3 A F6.1 A F8.1 F8.1 
  NEXT
endif
say -
"---------------------------------------------------------------------------"
sic output
!
! Edit the LaTeX report
!
!IF (DO_TEX) THEN
  SIC OUTPUT 'short_file'".tex"
  SAY "\documentstyle[rl,11pt,psfig]{article}"
!  SAY "\documentstyle[rl,psfig]{article}"
  SAY "\sloppy"
  SAY "\title {Project "'PROJECT'" Data File "'FILE_NAME'"\\"
  say "Observed on "'date_observed'" configuration "'telescope'-
  " ("'configuration'")}"
  SAY "\author{Automatic Calibration Report by CLIC x\_calib}"
  SAY "\begin{document}"
  SAY "\maketitle"
  say "\noindent \begin{tabular}{ll}"
  SAY " {\em Scan Range:} & " 'scan_range[1]' " to " 'scan_range[2]' "\\"
  SAY " {\em Use R1 phases for R2:} & " 'do_external' "\\"
  SAY " {\em Self cal. phases R1-$>$R2:} & " 'do_self' "\\"
  SAY " {\em Use phase correction:} & " 'do_atm' "\\"
  SAY " {\em Minimum Quality:} & " 'min_qual' "\\"
  SAY "\end{tabular}\hfill"
  if (nr.eq.2) then
    say "\begin{tabular}{|lll|}\hline"
    say " & Receiver 1 & Receiver 2 \\[2mm]"
    SAY "{\bf Bandpass:}&" 'RF_QUAL[1]'  "&" 'RF_QUAL[2]'    "\\"
    SAY "{\bf Phase:}   &" 'PHA_QUAL[1]' "&" 'PHA_QUAL[2]'   "\\" 
    if do_self then
      SAY "{\bf Seeing:} &$" seeing[1] "''$& - \\" -
                        /format a f4.2 a 
    else
      SAY "{\bf Seeing:} &$" seeing[1] "''$&$" seeing[2] "''$\\" -
                        /format a f4.2 a f4.2 a 
    endif
    SAY "{\bf Amplitude:} &" 'AMP_QUAL[1]' "&" 'AMP_QUAL[2]' "\\"
    SAY "\hline\end{tabular}\\"
  else if (nr.eq.1) then
    let ir irec[1]
    say "\begin{tabular}{|ll|}\hline"
    say " & Receiver "'ir'" \\[2mm]"
    SAY "{\bf Bandpass:} & " 'RF_QUAL[ir]'  "\\"
    SAY "{\bf Phase:}    & " 'PHA_QUAL[ir]' "\\"
    SAY "{\bf Seeing:}   &$" seeing[ir] "''$\\"  /format a f4.2 a 
    SAY "{\bf Amplitude:}& " 'AMP_QUAL[ir]' "\\"
    SAY "\hline\end{tabular}\\"
  endif

  SAY "\section{Summary}"
  SAY "\subsection{Calibrators:}"
  if (nr.eq.2) then
    if n_cals.gt.0 then
      say "\begin{center}\begin{tabular}{lrlrlrlrl}"
      say "&\multicolumn{4}{c}{" frghz[1] " GHz}&\multicolumn{4}{c}{" -
           frghz[2] " GHz}\\[2mm]"  /FORMAT a f5.1 a f5.1 a
      say "Fluxes (Jy): & ~~~~read && computed && ~~~~read && computed&\\"
      FOR I 1 TO N_cals
        let code1 " "
        let code2 " "
        let code3 " "
        let code4 " "
        let f1 rdi_FLUX[I,1]
        let f2 rdi_FLUX[I,2]
        if fix_flux[i,1] then
           let code2 "{\em Fixed}"
        endif
        if fix_flux[i,2] then
           let code4 "{\em Fixed}"
        endif
        if (cal_SOURCE[I].eq."CRL618") then
          let code1 "{\em Model}"
          let f1 fhii[1,1]
          let f2 fhii[1,2]
        else if (cal_SOURCE[I].eq."MWC349") then
          let code1 "{\em Model}"
          let f1 fhii[2,1]
          let f2 fhii[2,2]
        endif
        SAY "\verb|"'cal_SOURCE[I]'"|&" f1 "&"'code1'"&" cal_FLUX[I,1] -
           "&"'code2'"&" f2 "&"'code1'"&" cal_FLUX[I,2] "&"'code4'"\\" -
            /format a f6.2 a f6.2 a f6.2 a f6.2 a
      next
      say "\end{tabular}\end{center}"
    else
      say "{\em  No calibrators}"
    endif
  else if (nr.eq.1) then
    if n_cals.gt.0 then
      say "\begin{center}\begin{tabular}{lrlrl}"
      say " &" frghz[ir] "& GHz  &&\\[2mm]"  /FORMAT a f5.1 a
      say "Fluxes (Jy): & ~~~~read && computed &\\"
      FOR I 1 TO N_cals
        let code1 " "
        let code2 " "
        let f1 rdi_FLUX[I,ir]
        if fix_flux[i,ir] then
           let code2 "{\em Fixed}"
        endif
        if (cal_SOURCE[I].eq."CRL618") then
          let f1 fhii[1,ir]
          let code1 "{\em Model}"
        else if (cal_SOURCE[I].eq."MWC349") then
          let code1 "{\em Model}"
          let f1 fhii[2,ir]
        endif
        SAY "\verb|"'Cal_SOURCE[I]' "| &" f1 "&"'code1'"&" Cal_FLUX[I,ir] -
        "&"'code2'"\\"   /format a a f6.2 a f6.2 a
      next
      say "\end{tabular}\end{center}"
    else
      say "{\em  No calibrators}"
    endif
  endif
!
!
SAY "\subsection{Efficiencies:}  "
if (nr.eq.2) then
  say "\begin{center}\begin{tabular}{lrrlrr}"
  say "& Rec. " irec[1] " &     Rec. " irec[2] "& & &\\[2mm]"  -
                                /FORMAT a24 i1 a i1 a
  FOR I 1 TO NANT
    SAY "Antenna " I " (A" phys_ant[i] ") &" JYPK[I,1] "&" JYPK[I,2] -
    "& Jy /K  (&" CEFF[I,1] "&" CEFF[I,2] ")\\"                  -
     /FORMAT A i2 a i1 a F10.1 a F10.1 A f5.2 a f5.2 a
  NEXT
  say "\end{tabular}\end{center}"
else if (nr.eq.1) then
  say "\begin{center}\begin{tabular}{lrlr}"
  FOR I 1 To nant
    SAY "Antenna " I " (A" phys_ant[i] ") &" JYPK[I,ir] "& Jy /K (&" -
    CEFF[I,1] ")\\" -
     /FORMAT A i2 a i1 a F10.1 A  f5.2 A
  NEXT
  say "\end{tabular}\end{center}"
endif
!
SAY "\subsection{Observed Source(s):}  "
FIND /PROC CORR  /TYPE O
if (found.gt.0) then
  LIST /SOURCE
  say "\begin{center}\begin{tabular}{lllll}"
  FOR I 1 TO N_SOURCE
    FIND /SOURCE 'C_SOURCE[I]' /PROC CORR /TYP O
    IF (C_SOURCE[I].NE."W3OH".OR.FOUND.GT.10) THEN
       GET FIRST  /header
       LET HOURMIN 12*HOUR_ANGLE|PI
       GET CX_NUM[FOUND]  /header
       LET HOURMAX 12*HOUR_ANGLE|PI
       SAY "\verb|"'C_SOURCE[I]'"| & observed for Hour Angles &" -
           HOURMIN "&to& " HOURMAX "\\"   /FORMAT A F6.1 a F6.1 a
    ENDIF
  NEXT
  say "\end{tabular}\end{center}"
else
  say "{\em No project source observed}"
endif
SAY "\newpage"
SAY "\subsection{RF Bandpass:}"
say " RF Bandpass was measured on: " 'BAND_SOURCE' "\\"
if (nr.eq.2) then
  say "\begin{center}\begin{tabular}{r|rrrr|rrrr|}"
  say "Receiver &\multicolumn{4}{c|}{" irec[1] -
      "} & \multicolumn{4}{c|}{" irec[2] "}\\"  /FORMAT a i1 a i1 a
  say "Band & \multicolumn{2}{c}{LSB} & \multicolumn{2}{c|}{USB} " 
  say "     & \multicolumn{2}{c}{LSB} & \multicolumn{2}{c|}{USB} \\" 
  say "r.m.s. & Phase & Ampl. & Phase & Ampl. & Phase & Ampl. & Phase & Ampl. \\" 
  say "& (deg.) & (\%) & (deg.) & (\%) & (deg.) & (\%) & (deg.) & (\%) \\" 
  say "\hline"
  FOR I 1 TO NBAS
    SAY "Base"  basis[i] -
     "&" RF_LSB[2,I,1] "&" RF_LSB[1,I,1] "&" RF_USB[2,I,1] "&" RF_USB[1,I,1] -
     "&" RF_LSB[2,I,2] "&" RF_LSB[1,I,2] "&" RF_USB[2,I,2] "&" RF_USB[1,I,2] -
     "\\" /FORMAT A I3 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a
  NEXT
  say "\end{tabular}\end{center}"
else if (nr.eq.1) then
  say "\begin{center}\begin{tabular}{r|rrrr|}"
  say "Band & \multicolumn{2}{c}{LSB} & \multicolumn{2}{c|}{USB} \\" 
  say "r.m.s. & Phase & Ampl. & Phase & Ampl. \\" 
  say "& (deg.) & (\%) & (deg.) & (\%) \\"
  say "\hline" 
  FOR I 1 TO NBAS
    SAY "Base"  basis[i] -
  "&" RF_LSB[2,I,ir] "&" RF_LSB[1,I,ir] "&" RF_USB[2,I,ir] "&" RF_USB[1,I,ir] -
  "\\"  /FORMAT A I3 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a F8.1 a
  NEXT
  say "\end{tabular}\end{center}"
endif
!
say "\subsection{Time dependence:}"
if (nr.eq.2) then
  if .not.do_self then
    say "\begin{center}\begin{tabular}{rr|rr|rr|}"
    say "& Receiver &\multicolumn{2}{c|}{" irec[1] -
      "} & \multicolumn{2}{c|}{" irec[2] "}\\"  /FORMAT a i1 a i1 a
    say "&r.m.s. & Phase & Ampl. & Phase & Ampl. \\"
    say "&    & (deg.) & (\%) & (deg.) & (\%)\\ \hline" 
  else
    say "\begin{center}\begin{tabular}{rr|rr|rrr|}"
    say "& Receiver &\multicolumn{2}{c|}{" irec[1] -
      "} & \multicolumn{3}{c|}{" irec[2] "}\\"  /FORMAT a i1 a i1 a
    say "&r.m.s. & Phase & Ampl. & Phase & (self) & Ampl. \\"
    say "&    & (deg.) & (\%) & (deg.) & (deg.) & (\%)\\ \hline" 
  endif
  FOR I 1 TO NBAS
    LET BB NINT(SQRT(BASELINE[1,I]^2+BASELINE[2,i]^2+BASELINE[3,i]^2))
    if .not.do_self then
      SAY "Base"  basis[i] " &(" BB  " m)&" -
        PHA_ERR[I,1] "&" AMP_ERR[I,1] "&" PHA_ERR[I,2] "&" AMP_ERR[I,2] "\\" -
         /FORMAT  A6 I3 A F6.1 A F8.1 a F8.1 a F8.1 a F8.1  a 
    else
      SAY "Base"  basis[i] " &(" BB  " m)&" -
        PHA_ERR[I,1] "&" AMP_ERR[I,1] "&" -
        PHA_ERR[I,1]*frghz[2]|frghz[1] "&(" PHA_ERR[I,2] ")&" -
        AMP_ERR[I,2] "\\" -
         /FORMAT  A6 I3 A F6.1 A F8.1 a F8.1 a F8.1 a F8.1 a F8.1  a 
    endif 
  NEXT
  say "\end{tabular}\end{center}"
else if (nr.eq.1) then
  say "\begin{center}\begin{tabular}{rr|rr|}"
  say "&r.m.s. & Phase & Ampl. \\"
  say "&    & (deg.) & (\%) \\ \hline" 
  FOR I 1 TO NBAS
    LET BB NINT(SQRT(BASELINE[1,I]^2+BASELINE[2,i]^2+BASELINE[3,i]^2))
    SAY "Base"  basis[i] " &(" BB  " m)&" -
        PHA_ERR[I,ir] "&" AMP_ERR[I,ir] "\\" -
         /FORMAT  A6 I3 A F6.1 A F8.1 a F8.1 a 
  NEXT
  say "\end{tabular}\end{center}"
endif

  SAY "\newpage"
  for kr 1 to 2
    let ir irec[kr]
    if irec[kr].gt.0 then
      SAY "\section{Receiver "'ir'"}"
      SAY "\subsection{Efficiency Plot}"
      let plotps 'short_file'"-eff-"'ir'".ps"
      if file(plotps) then
        SAY "\psfig{file="'plotps'",width=16.0cm}"
      else
        SAY "{\em Missing plot file}\\"
      endif
      if (cal_band[ir].eq."LSB").or.(cal_band[ir].eq."DSB") then
        SAY "\subsection{LSB Bandpass}"
        let plotps 'short_file'"-rflsb-"'ir'".ps"
        if file(plotps) then
          SAY "\psfig{file="'plotps'",width=16.0cm}"
        else
          SAY "{\em Missing plot file}\\"
        endif
      endif
      if (cal_band[ir].eq."USB").or.(cal_band[ir].eq."DSB") then
        SAY "\subsection{USB Bandpass}"
        let plotps 'short_file'"-rfusb-"'ir'".ps"
        if file(plotps) then
          SAY "\psfig{file="'plotps'",width=16.0cm}"
        else
          SAY "{\em Missing plot file}\\"
        endif
      endif
      SAY "\subsection{Phase Calibration}"
      let plotps 'short_file'"-ph-"'ir'".ps"
      if file(plotps) then
        SAY "\psfig{file="'plotps'",width=16.0cm}"
      else
        SAY "{\em Missing plot file}\\"
      endif
      SAY "\subsection{Amplitude Calibration}"
      let plotps 'short_file'"-am-"'ir'".ps"
      if file(plotps) then
        SAY "\psfig{file="'plotps'",width=16.0cm}"
      else
        SAY "{\em Missing plot file}\\"
      endif
    endif
  next
  SAY "\end{document}"
SIC OUTPUT
!
! save output with a meaningful name
!
if SIC$VERSION.EQ."HPUX".or.SIC$VERSION.EQ."Generic Unix" then
  sic\system "latex "'short_file'".tex"
  sic\system "dvips -o "'short_file'".ps "'short_file'
  sic\system "chmod g+w "'short_file'"*.*"
else if SIC$VERSION.EQ."WIN32" then
  sic\system "latex "'short_file'".tex"
  sic\system "dvips -o "'short_file'".ps "'short_file'
else
  say "... not yet available for "'SIC$VERSION'
endif
sic\say "I-PRINT, Postcript report is "'short_file'".ps"
sic\say "I-PRINT, Summary text report is "'short_file'".sum"