!------------------------------------------------------------------------------
begin procedure single_file_all
   define character tname*80 
   for i 1 to n_cont
     let tname conttable_'i' /format a80
     @ single_file 'tname'
   next
   for i 1 to n_line
     let tname linetable_'i' /format a80
     @ single_file 'tname'
   next
end procedure single_file_all
!------------------------------------------------------------------------------
begin procedure single_file
   if table_status.eq."NEW" then
      system "rm "'proj'"-&1*.uvt"
   endif
   @ 'proj'-&1
end procedure single_file
!------------------------------------------------------------------------------
begin help x_newt_sngl.hlp

Table Creation/Extension Panel

This is the window used to create and extend tables for a given
project.  It has a button to create/extend all tables, and for each
table (line or continuum) a button to create or extend it.

The name of the input file is in variable FILE_NAME

The INPUT button may be used to select the table parameters.
Click on INPUT Parameters if you want to change the number of tables.

Inputs:
-------

2 TABLE_STATUS
	Choose between OLD and NEW; decides whether the tables are 
        created or extended.

2 FILE_NAME
	The input data file. Press FILE to browse for the file name.

end help    x_newt_sngl.hlp
!------------------------------------------------------------------------------
! MAIN procedure: x_newtable_single.clic
!------------------------------------------------------------------------------
define character tname*80 text*80 ptext*80
@ x_newproject.astro
!
if .not.exist(project_entered) then
   return
endif
exa project_entered
!
if .not.exist(file_name) then
  define character file_name*80 /global
endif
if .not.exist(table_status) then
  define character table_status*3 /global
endif
if ("'sys_info'".ne."observer") then    ! rn
   let table_status OLD
 else
   let table_status NEW
endif
! 
! Buttons:
!
gui\panel "Table creation panel for project "'proj'" (one data file)" -
    x_newt_sngl.hlp
gui\button "@ single_file_all"  "All tables" 
for i 1 to n_cont
   let tname conttable_'i' /format a80
   gui\button "@ single_file "'tname' 'tname'
next
for i 1 to n_line
   let tname linetable_'i' /format a80
   gui\button "@ single_file "'tname' 'tname'
next
let table_status  'table_status'	/prompt "Table status" -
                                        /choice NEW OLD
let file_name  'file_name'   /prompt "file name " /file "*.hpb"

gui\button "@ project_input" "INPUT" "Table Parameters" table_input.hlp -
   "Parameters"
   let proj  'proj'       /prompt "Project name ?"
   let n_cont  	'n_cont' 	/prompt "number of continuum tables ?"
   let n_line	'n_line'	/prompt "number of line tables ?"
gui\button "@ x_newproject.astro RESET" "RESET"
gui\go     "@ single_file_all"        "All tables"