!
! #1 written by A.Dutrey
! #2 modified by R.Neri / creates procedure "'tname'-table.clic"
! #3 modified by R.Neri / baseline-based vs antenna-based
! #4 modified by R.Neri / lower case source name and "set def" at start
! #5 22/12/98 modified by A.Dutrey / option resample & Line now ok +
! change position buttons ``baseline-based'' and ``atm phase corr''
! modify also the default directory where the .uvt are written (MAPS)
!
! Init data file 
FILE IN 'TFILE'
VAR RF_SETUP ON
SET SCAN TSCAN[1] TSCAN[2]
SET OFFSET TOFFSETS[1] TOFFSETS[2] 
SET RECEIVER TREC
sys "echo "'TSOURCE'" > .del"
sys "typeset -u ts; read -r ts < .del; echo SET SOU $ts > .del.clic"
@.del.clic
sys "rm -f .del*"
SET QUALITY 'TQUAL'
FIND /PROC COR
IF (FOUND.EQ.0) THEN
   SAY "E-Create_Table,  No CORR for source "'TSOURCE'
   RETURN
ENDIF
!
! Init calib
SET PHA ANT 
SET AMP ANT
SET RF ANT
SET WEIGHT TSYS ON
SET WEIGHT CALIB ON
IF (TREC.EQ.1) THEN
  SET PHASE REL INTERNAL
ELSE 
  SET PHASE REL EXTERNAL  
ENDIF 
SET RF ON FREQ
SET AMP ABS
SET AMP REL
IF (TDOPHASE) THEN
  SET PHASE ATM
ELSE
  SET PHASE NOATM
ENDIF
!
! Create table
DEFINE CHARACTER SUB*3[6]
DEFINE INTEGER JBAND 
!DEFINE REAL FREQ
!
LET JBAND 0
!
DEFINE LOGICAL SELECT[6]
LET SELECT TDOSUB1 TDOSUB2 TDOSUB3 TDOSUB4 TDOSUB5 TDOSUB6 
DEFINE CHARACTER SELECTION*64
FOR I 1 TO 6
IF (SELECT[I]) THEN
  LET JBAND JBAND+1
  IF (JBAND.EQ.1) THEN
    LET SELECTION "L0"'I'" "
  ELSE
    LET SELECTION 'SELECTION'" AND L0"'I'
  ENDIF
ENDIF
NEXT
!
SYMBOL SELECTIO 'SELECTION'
DELETE /VAR SELECTION
!SYMBOL SELECTIO
SAY "SET SELECT "'TMODE'" "'TBAND' 'SELECTIO'
SET SELECT 'TMODE' 'TBAND' 'SELECTIO'
!SHOW SELECTION
define character ttname*12
if (ttname.eq.tname) then
 say " "
 say " Missing output table filename !!"
 return
endif
if (tsource.eq."*") then
 say " "
 say " Source name is undefined !!"
 return
endif
!
! For old table, options are meaningless
!
! modified by rn on May 12, 1998
! modified by AD on Dec 22, 1998
if (.not.tstatus) then 
   sys "rm -f table-update.clic"
   sys "!mv -f "'TNAME'"-table.clic table-dummy.clic"
 else
   sys "!echo set def > "'TNAME'"-table.clic" 
endif
!
sys "!echo !! >> "'TNAME'"-table.clic" 
sys "!echo file in '\042'!"'TFILE'"'\042' >> "'TNAME'"-table.clic"
sys "!echo ! >> "'TNAME'"-table.clic"
sys "!echo set scan "'TSCAN[1]'" "'TSCAN[2]'" >> "'TNAME'"-table.clic"
sys "!echo set offset "'TOFFSETS[1]'" "'TOFFSETS[2]'" >> "'TNAME'"-table.clic"
sys "!echo set receiver "'TREC'" >> "'TNAME'"-table.clic"
sys "!echo set quality "'TQUAL'" >> "'TNAME'"-table.clic"  
sys "!echo ! >> "'TNAME'"-table.clic"
sys "!echo set weight tsys on >> "'TNAME'"-table.clic"
sys "!echo set weight calibration on >> "'TNAME'"-table.clic"
!
if (trec.eq.1) then
  if (tdophase) then
    if (.not.tdoant) then
      SET PHASE BASELINE
      sys "!echo set phase baseline atmospher internal relative >> "'TNAME'"-table.clic"
    else
      SET PHASE ANTENNA
      sys "!echo set phase antenna atmospher internal relative >> "'TNAME'"-table.clic"
    endif
  else
    if (.not.tdoant) then
      SET PHASE BASELINE
      sys "!echo set phase baseline noatmospher internal relative >> "'TNAME'"-table.clic" 
    else
      SET PHASE ANTENNA
      sys "!echo set phase antenna noatmospher internal relative >> "'TNAME'"-table.clic" 
    endif
  endif
else
  if (tdophase) then
    if (.not.tdoant) then
      SET PHASE BASELINE
      sys "!echo set phase baseline atmospher external relative >> "'TNAME'"-table.clic" 
    else
      SET PHASE ANTENNA
      sys "!echo set phase antenna atmospher external relative >> "'TNAME'"-table.clic" 
    endif
  else
    if (.not.tdoant) then
      SET PHASE BASELINE
      sys "!echo set phase baseline noatmospher external relative >> "'TNAME'"-table.clic" 
    else
      SET PHASE ANTENNA
      sys "!echo set phase antenna noatmospher external relative >> "'TNAME'"-table.clic" 
    endif
  endif
endif
if (.not.tdoant) then
  SET AMPLITUDE BASELINE
  sys "!echo set amplitude baseline absolute jansky relative >> "'TNAME'"-table.clic"
  SET RF BASELINE
  sys "!echo set rf_passband baseline frequency file on >> "'TNAME'"-table.clic"
else
  SET AMPLITUDE BASELINE
  sys "!echo set amplitude antenna absolute jansky relative >> "'TNAME'"-table.clic"
  SET RF BASELINE
  sys "!echo set rf_passband antenna frequency file on >> "'TNAME'"-table.clic"
endif
!
!
sys "!echo ! >> "'TNAME'"-table.clic"
sys "!echo set selection "'TMODE'" "'TBAND'" 'SELECTIO' >> "'TNAME'"-table.clic"
sys "!echo find /proc corr  /sou "'TSOURCE'" >> "'TNAME'"-table.clic"
!
CLIC\SHOW RF
CLIC\SHOW PHASE	! Pour qu'on connaisse les modifs si Baseline-based AD !
CLIC\SHOW AMPLITUDE
PAUSE		! Faut aussi changer le Pause de place AD !
!
IF (TSTATUS) THEN 
  IF (TMODE.EQ."CONT") THEN
    sys "!echo table '\042'"'TNAME'"'\042' new >> "'TNAME'"-table.clic" 
  ELSE 
    IF (TLINENN) THEN
      IF (TRESAMP) THEN
         sys "!echo table '\042'"'TNAME'"'\042' new /freq "'TNFREQ'" "'TFFREQ'" /res "'TCHANNELS'" "'TREF'" "'TVAL'" "'TRESA'" VELO >> "'TNAME'"-table.clic"
      ELSE
        sys "!echo table '\042'"'TNAME'"'\042' new /freq "'TNFREQ'" "'TFFREQ'" >> "'TNAME'"-table.clic"
      ENDIF
    ELSE IF (TRESAMP) THEN
      sys "!echo table '\042'"'TNAME'"'\042' new /res "'TCHANNELS'" "'TREF'" "'TVAL'" "'TRESA'" VELO >> "'TNAME'"-table.clic"
    ELSE 
      sys "!echo table '\042'"'TNAME'"'\042' new >> "'TNAME'"-table.clic" 
    ENDIF
  ENDIF
  @ 'tname'"-table.clic"
ENDIF
IF (.NOT.TSTATUS) THEN 
  sys "!echo table "'TNAME'" >> "'TNAME'"-table.clic"
  sys "!cp "'TNAME'"-table.clic table-update.clic"
  sys "!cat "'TNAME'"-table.clic >> table-dummy.clic"
  sys "!mv -f table-dummy.clic "'TNAME'"-table.clic"
  @table-update.clic
ENDIF
!
!AD! SIC DIR "~/HEADERS/"