!------------------------------------------------------------------------ 
! FITHEADER.GRAPHIC 
! Procedure to plot header information for uv plots 
! Variables defined in DEFINE.GRAPHIC 
! Created R.Lucas 22-nov-1990 
! modified r.neri 23-may-1993 
!------------------------------------------------------------------------ 
on error return 
def character text*40 
define logical landscape 
define real boxs xbox ybox 
! 
let landscape page_x.gt.page_y 
let xbox 5*character_size 
let ybox 3*character_size 
if (landscape) then 
  let boxs min(page_x-0.1-xbox-13*character_size,page_y-ybox-0.1) 
  if (boxs.lt.0) then 
    say "F-HEADER, Page to small - change page or decrease character size" 
    quit all 
  endif 
  set box xbox+boxs page_x ybox page_y-0.1 
else 
  let boxs min(page_x-xbox-0.1,page_y-13*character_size-0.1) 
  if (boxs.lt.0) then 
    say "F-HEADER, Page to small - change page or decrease character size" 
    quit all 
  endif 
  set box xbox xbox+boxs ybox+boxs page_y-0.1 
endif 
box n n n 
! 
set expand 1.0 
let text "'NAME'.TUV" 
dra text .5 -1 'text' 6 /box 7 
! 
set expand 0.8 
let text "\\iSource:\\i 'F%SOURCE'" 
dra text .5 -2 'text' 6 /box 7 
! 
let text "\\iLine:\\i 'F%LINE'" 
dra text .5 -3 'text' 6 /box 7 
! 
let text "\\iFrequency:\\i '1D-6*NINT(F%RESTFRE*1000)' GHz" 
dra text .5 -4 'text' 6 /box 7 
! 
if (first.eq.0).and.(last.eq.0) then 
  let text "\\iAll Channels" 
else 
  let text "\\iChannels:\\I 'FIRST' to 'LAST'" 
endif 
dra text .5 -5 'text' 6 /box 7 
! 
let text "'YTYPE' \\ivs.\\i 'XTYPE'" 
dra text .5 -6 'text' 6 /box 7 
! 
if (mark.ne."FREQUENCY".and.mark.ne."CHANNEL") then 
  let mark "VELOCITY" 
endif 
let text "\\iBox marking:\\i 'MARK'" 
dra text .5 -7 'text' 6 /box 7 
! 
let text "\\iFitted model:\\i 'FIT'" 
if (fit.ne."") then 
  dra text .5 -8 'text' 6 /box 7 
endif 
! 
sic date 
dra text 0.0 2.0 "'SYS_INFO'" 5 /box 2 
dra text 0.0 1.0 "'SYS_DATE'" 5 /box 2 
set box xbox xbox+boxs ybox ybox+boxs 
! BOX N N N