if (aaa%ndim.ne.3) then 
  return 
endif 
create directory <spe /pixel 450 315 
! 
! added AAA needed if scale is automatic (RL) 
@ p_scale.greg aaa 
say "I-LINE, Type any character to display spectrum, Q or E to exit" 
change directory <greg 
define integer ibox jbox ix iy ip np 
let np aaa%dim[3] 
define double xp[np] yp[np] 
let xp[i] (i-aaa%convert[1,3])*aaa%convert[3,3]+aaa%convert[2,3] 
! 
let cursor_code " " 
! 
for /while .true. 
  draw relo 
  let ibox 0 
  let jbox 0 
  for i 1 to nbox 
    if (x_pen.ge.ubox[1,i,1]).and.(x_pen.lt.ubox[2,i,1]) then 
      let ibox = i 
    endif 
  next 
  for j 1 to mbox 
    if (y_pen.ge.ubox[3,1,j]).and.(y_pen.lt.ubox[4,1,j]) then 
      let jbox = j 
    endif 
  next 
  if (ibox.eq.0).or.(jbox.eq.0) then 
    let ip = 0 
  else 
    let ip nint(ubox[5,ibox,jbox]) 
  endif 
                                ! 
  if (cursor_code.eq."Q".or.cursor_code.eq."E") then 
    break 
  else if (cursor_code.eq."Z") then 
    zoom refresh 
  else 
    if (ip.eq.0) then 
      say "W-LOOK, Pen is not in any plane" 
    else 
      say " " 
      say "I-LOOK, Pen is in plane " 'ip' 
      on error continue 
      change directory p'ibox'-'jbox' 
      draw ? * * 
      let ix pix_curs[1] 
      let iy pix_curs[2] 
      say "Map Value at Pixel ("'ix'","'iy'") = "'aaa[ix,iy,ip]' 
      change directory .. 
      let yp aaa[ix,iy,] 
      change directory <spe 
      clear directory <spe 
      change position 7 
      limit * * true_scale[1] true_scale[2] /var xp yp 
      set box land 
      box 
      histo xp yp 
      label "Velocity (km/s)" /x 
      label "Flux Density (Jy)" /y 
      draw relo xp[ip] true_scale[1] /user 
      draw line xp[ip] true_scale[2] /user 
      change directory <greg 
      on error 
    endif 
  endif 
next