!------------------------------------------------------------------------ 
! C_HEADER.MAP 
! Procedure to plot header information for contour plots in MAPPING 
! (Unused ?) 
!------------------------------------------------------------------------ 
on error return 
def character text*40 
define logical landscape 
define real boxs xbox[2] ybox[2] 
! 
let landscape page_x.gt.page_y 
let xbox box_xmin 
let xbox[2] box_xmax 
let ybox box_ymin 
let ybox[2] box_ymax 
if (landscape) then 
  set box box_xmax page_x-0.1 box_ymin box_ymax 
else 
  set box box_xmin box_xmax box_ymax page_y-0.1 
endif 
box n n n 
set expand 1.0 
! 
dra text .5 -1 'd_type' 6 /box 7 
set expand 0.8 
! 
let text "\\iSource:\\i "'z_source' 
dra text .5 -2 'text' 6 /box 7 
! 
let text "\\iLine:\\i "'z_line' 
dra text .5 -3 'text' 6 /box 7 
! 
let text "\\iFrequency:\\i "'1d-6*nint(z_restfre*1000)'" GHz" 
dra text .5 -4 'text' 6 /box 7 
! 
if (z_major.ne.0) then 
  define integer imajor iminor ipa 
  let imajor nint(z_major*180*3600|pi*10) 
  let iminor nint(z_minor*180*3600|pi*10) 
  let ipa nint(z_pa*180.0|pi) 
  let text "\\iBeam:\\i "'0.1*imajor'" x "'0.1*iminor'" PA "'ipa'"^" 
else 
  let text "\\iBeam:\\i (no clean beam)" 
endif 
dra text .5 -5 'text' 6 /box 7 
if (spacing.ge.0) then 
  if (true_spacing.gt.0.01) then 
    let text "\\iLevel spacing:\\i "'nint(true_spacing*1000.)'" mJy" 
  else 
    let text "\\iLevel spacing:\\i "'0.1*nint(true_spacing*10000.)'" mJy" 
  endif 
else 
  let text "\\iLevel spacing:\\i (user list)" 
endif 
dra text .5 -6 'text' 6 /box 7 
! 
!IF (MARK.NE."CHANNEL") THEN 
!    IF (Z_UNIT3.EQ."RA").OR.(Z_UNIT3.EQ."DEC") THEN 
!	LET MARK "'Z_UNIT3' offset" 
!    ELSE IF (MARK.NE."FREQUENCY") THEN 
!	LET MARK "VELOCITY" 
!    ENDIF 
!ENDIF 
!LET TEXT "\\iBox marking:\\i 'MARK'" 
!DRA TEXT .5 -7 'TEXT' 6 /BOX 7 
! 
if (context.ne.0) then 
  define real arange 
  if (range[1].eq.0.and.range[2].eq.0) then 
    if (z_extrema.eq.0) then    ! means no extrema section 
      symbol dtype 'd_type' 
      compute z_min min 'dtype' 
      compute z_max max 'dtype' 
      let z_extrema 2 
    endif 
    let true_range z_min z_max 
  else 
    let true_range range 
  endif 
  let arange max(abs(true_range[1]),abs(true_range[2])) 
  draw text 0.5 -8 "\\iColour Range:\\i" 6 /box 7 
  if (arange.gt.0.1) then 
    let text '1e-3*nint(true_range[1]*1e3)'" to " '1e-3*nint(true_range[2]*1e3)'" Jy" 
  else 
    let text '1e-2*nint(true_range[1]*1e5)'" to " '1e-2*nint(true_range[2]*1e5)'" mJy" 
  endif 
  dra text .5 -8-character_size 'text' 6 /box 7 
endif 
! 
sic\sic date 
dra text 0.0 2.0 "'SYS_INFO'" 5 /box 2 
dra text 0.0 1.0 "'SYS_DATE'" 5 /box 2 
set expand 1.0 
set box xbox[1] xbox[2] ybox[1] ybox[2] 
on error