! Procedure onfmpt.nic create a file for the ON-OFF mapping of one source
!	where flux and coordinate are written
!	the multipoint map will be showed
symbol firstscan /inquire "First scan : "
symbol lastscan /inquire "Last scan : "
symbol ext /inquire "Extension of the output file : "
say "Output file will be called onoff."'ext'
say " "
define real tau
say "Initialisation of mean opacity calibration factor :"
let tau
let counts_per_jy
say "Mean zenith opacity can be changed for each scan"
say "Calibration factor can either be changed for each scan" 
say "If you agree with the current values, just type <RETURN>"
say " "
sic output onoff.'ext'

on error continue
for i 'firstscan' to 'lastscan'
  sic search bolo_data:'i'.nmb

  if sic$exist then
    file in bolo_data:'i'

    set gain_amplifier
    set gain_elevation
    set gain_channel

    var sky on write
    if i.eq.'firstscan' then
       let scan_opacity tau
       del /var tau
    endif
    exa scan_opacity
    let scan_opacity
    set opacity on scan_opacity
    var sky on read

    exa counts_per_jy
    let counts_per_jy
    set jansky on counts_per_jy

    var *
    onoff
  endif
next

sic output
del /sym firstscan lastscan
pause
!
!
cl pl
column X 3 Y 4 Z 5 /file "onoff.'ext'"
var antenna write
let beam_az
let beam_el
var antenna read
limits /reverse X
set box match
GREG2\ELLIPSE beam_az|2 beam_el|2 /USER USER_XMIN-10 USER_YMAX-10
symbol spoint /inquire "spoint (20 20) ?"
GREG2\RANDOM_MAP 'spoint' /BLANKING -1000 1
SYMBOL SPLOT "N"
SYMBOL SPLOT /INQUIRE "Display obs. points ? [Y/N] ="
if ("'SPLOT'".ne."N") then
   set marker 8 0 .15
   POINT
endif
!
set marker 8 3 .3
draw marker	    0.	   0.	/USER
!
extr /c
PAUSE
symbol SLEV /inquire "levels ?"
GREG2\LEVELS 'slev'
GREG2\RGMAP /ABSOLUTE 1
!
SYMBOL ABS "N"
SYMBOL ABS /INQUIRE "COORD ABS ? [Y/N] ="
if ("'ABS'".ne."N") then
    SET SYSTEM EQUATORIAL
    SET ANGLE SECO
    header
    SYMBOL proj /inquire "CENTER ? (9:51:43.4 69:55:5.3)"
    PROJECTION 'proj' /type radio
    limits /reverse x
    box /abs
    LABEL "\Ga(1950)" /X
    LABEL "\Gd(1950)" /Y
ELSE
    box
    LABEL "\GD\Ga(arcsec)" /X
    LABEL "\GD\Gd(arcsec)" /Y
ENDIF
!
DRAW T 0.0 0.5 'SOURCE'" AT 1.3 MM   LEVELS: 'SLEV' mJy/beam" 8 /BOX 8
!col x 1 y 2 /file cata2.samp
!set marker 5 1 .4
!convert 00:08:47.45 58:32:48.1 /system equa /unit sec /type radio
!point