! Procedure radec.nic
! Calcule les offsets en alpha/delta associe a chacun des bolometres du scan 
! considere.
! &1 nb de bolometres consideres
! &2 Delta_RA[nbolom]
! &3 Delta_Dec[nbolom]
!
! Calcul des positions des offset en az/el
! Quelques moyennes sur le scan lst en sec de temps
define real ttempo[nrecord,1] wei[nrecord,1]/global
let wei 1
for i 1 to nrecord
   let ttempo[i,1] lst[i]
next
define integer nbolom/global
let nbolom &1
define real mean_lst rms_lst/global
@wmean ttempo wei 1 nrecord mean_lst rms_lst 1
del/var ttempo wei
!
! Calcul de l'angle paralactique pa moyen (en degres) et 
! de l'elevation de la source Elv_s(en radians)
define real d_to_r
let d_to_r pi|180   	!convert degrees to radians
define real HA sinHA cosHA Dec sind cosd phi sinphi cosphi
define real pa cospa sinpa Elv_s cosel sinel
!
!Les angles Dec, Phi et HA sont en radians et HA dans [-pi,pi]
let Dec    beta*d_to_r
let phi    site_latitude
let HA     (mean_lst*15.|3600-lambda)*d_to_r
!
let sind   sin(Dec)
let cosd   cos(Dec)
let sinphi sin(phi)
let cosphi cos(phi)
let sinHA  sin(HA)
let cosHA  cos(HA)
!
! Elevation
 let sinel sind*sinphi+cosd*cosphi*cosHA
 let Elv_s asin(sinel)
 let cosel cos(Elv_s)
!
! Paralactic angle
let cospa (sinphi-sinel*sind)|(abs(cosel)*cosd)
let pa acos(cospa)|d_to_r
if (HA.gt.pi) then
   let HA HA-2*pi
else
   if (HA.lt.-pi) then
      let HA HA+2*pi
   endif
endif
if (HA.le.0.) then
   let pa -pa
endif
!exa pa
let sinpa sin(pa*d_to_r)
!
del/var HA sinHA cosHA Dec sind cosd phi sinphi cosphi cosel sinel
del/var mean_lst rms_lst
!
!
! Position des bolometres en az/el
define real Daz_b[nbolom] Del_b[nbolom] oe oa RA[nbolom] DEC[nbolom]
! Les offsets du reseau par rapport a la source cartographiee
let oa OAZM*3600+wobbler_throw|2*unbal          !en arcsec
let oe OELV*3600                                !en arcsec
!exa oa
!exa oe
!
! Rotation des coord de la cabine des recepteurs a cause de Elv_s
for k 1 to nbolom
! Inutile dans le cas nchan=19 au lieu de 23
   let Daz_b[k] -chan_az_off[k]*cos(Elv_s)+chan_el_off[k]*sin(Elv_s)
   let Del_b[k]  chan_az_off[k]*sin(Elv_s)+chan_el_off[k]*cos(Elv_s)
next
let Daz_b Daz_b+oa
let Del_b Del_b+oe
! Passage en coord RA/DEC
let RA -Daz_b*cospa+Del_b*sinpa
let DEC Daz_b*sinpa+Del_b*cospa
let &2 RA
let &3 DEC
!lim/var RA DEC /reverse x
!set box_location 2 18 2 18
!cl pl
!box
!point RA DEC
!pause
del/var Daz_b Del_b pa cospa sinpa oa oe RA DEC nbolom