! Procedure standard.nic 
! created by Motte Frederique (motte@gag.observ-gr.fr) 22-MAR-95
! permit a first order and fast reduction of the ON-THE-FLY map with NIC
! Run : @ standard
! 
!
symbol numero /inquire "Scan number to reduce : "

! Despiking and calibrating the signal
signal 'numero'
symbol rep /inquire "despiking ? [Y/N] "
if "'rep'".eq."Y" then
   flag /channel 6
   var data write
   let signal[6] 0
   despike /iter 3 /interp
   signal
   say "If there is no spike left, we can continue"
   cl al
   pause
endif
!
set gain_amplifier on	    ! bolgain set during observation
set gain_channel on	    ! relative gains of each bolometer to the first one
set gain_elevation on       ! elevation gain traces antenna deformation with El
define real tau
say "Mean zenith opacity ?"
let tau
set opacity on tau          ! opacity calibration
say "Calibration factor (counts/Jy) ?"
let Counts_per_Jy
set jansky on counts_per_jy ! Calibration factor to physical map unit
!
! Removing a baseline on the double-beam maps
signal
var *
makplan
map
cl al
pause
define logical EM_FREE
say "Are the edges in Azimuth of the map emission free ? [yes/no]"
let EM_FREE
if EM_FREE then
   for i 1 to nchan
     baseline /order 1 /bysubscan /support beamsep|2 beamsep|2 -80 /chan i
   next
   makplan
   map
else
   baseline /support beamsep|2 beamsep|2 -80 /apply /file 'source'.'scan' new
   makplan
   map
   define logical POLY_APPLY DO_BASE
   say "You will define a polygon, outside there must be emission free"
   say "Do you want to apply the same polygon to each bolometer ? [yes/no]"
   let POLY_APPLY
   LET DO_BASE = .TRUE.
   if POLY_APPLY then
      FOR /WHILE DO_BASE
         baseline /order 1 /apply /bysubscan
         makplan
         map
         let DO_BASE = .FALSE.
         EXA DO_BASE
         say "Baseline removal OK ? --> DO_BASE = .FALSE."
         LET DO_BASE =  
      NEXT
   else
      say "For a better baseline, just do it by yourself !!!"
      pause
      makplan
      map
   endif
endif
!
! Restoring the double-beam maps
say "The chopper throw is set to : "'beamsep'
say "Give a new value for the chopper_throw (I propose "'beamsep-1'") :"
let beamsep
restore
map
cl al
pause
!
! Converting the multi-channel maps
flag /channel 6
say "Before conversion, you have to say witch channel will be used"
say "If you don't want to use the channel 3, type   FLAG /CHANNEL 3"
pause
flag
flag /channel 6
convert
map