SUBROUTINE VDTFN (
*
*  inputs
*
     :                  VAR, COEFF,
*
*  outputs
*
     :                  F0, FVAR, FCOEFF)
*
*  Module number: 15.5.2.3.1
*
*  Module name: deadtimev
*
*  Keyphrase:
*  ----------
*  Calculate functional values and derivatives of the pair-pulse correction
*  equation.
*
*  Description:
*  ------------
*  For the function:
*
*       F = A * X / (1 + A * X * tau) - Y
*
*  calculate the functional value F0, for given A, tau, X, and Y.  Also
*  calculate the partial derivatives of F relative to A and tau
*  (coefficents) and X, and Y (variables).
*
*  COEFF(1) = tau, COEFF(2) = A, VAR(1) = X, VAR(2) = Y
*
*  FORTRAN name: VDTFN.FOR
*
*  Keywords of accessed files and tables:
*  --------------------------------------
*  Name                         I/O     Description / Comments
*       None
*
*  Subroutines Called:
*  -------------------
*  CDBS:
*       None
*  SDAS:
*       None
*  Others:
*       None
*
*  History:
*  --------
*  Version      Date        Author          Description
*     1       11-16-85     J.-C. HSU        design and coding
*     1       08-20-87     J.-C. HSU        F77 standard
*
*-------------------------------------------------------------------------------
*
*== input:
*                                       --observed variables at a given point
*                                       --(e. g. X and Y coordinates)
        DOUBLE PRECISION        VAR(*),
*                                       --coefficients in the given function
     :                          COEFF(*)
*
*== output:
*                                       --functional value
        DOUBLE PRECISION        F0,
*                                       --partial derivativeS relative to the
*                                       --variables and coefficients
     :                          FVAR(*), FCOEFF(*)
*
*== local:
*                                       --dummy
        DOUBLE PRECISION        DUMMY
*
*------------------------------------------------------------------------------
*
*  functional value
*
        DUMMY = (1.D0 + COEFF(2) * VAR(1) * COEFF(1))
        F0 = COEFF(2) * VAR(1) / DUMMY - VAR(2)
*
*  partial derivatives relative to the variables
*
        FVAR(1) = COEFF(2) / DUMMY ** 2
*
        FVAR(2) = -1.D0
*
*  partial derivatives relative to the coefficients
*
        FCOEFF(1) = - (COEFF(2) * VAR(1) / DUMMY) ** 2
*
        FCOEFF(2) = VAR(1) / DUMMY ** 2
*
        RETURN
        END