SUBROUTINE CDPGT (
*
*  outputs
*
     :                  COUNT, DCOUNT, APPA, TEMP, EPOCH, APERT, TARGET,
     :                  NPTS, OFILE, STATUS)
*
*  Module number:
*
*  Module name:
*
*  Keyphrase:
*  ----------
*  Input parameters and data needed for polarimetric calibration routines
*
*  Description:
*  ------------
*
*  FORTRAN name: CDPGT.FOR
*
*  Keywords of accessed files and tables:
*  --------------------------------------
*  Name                         I/O     Description / Comments
*
*       CL parameters:
*
*  'intable'                     I      input table name
*  'outtable'                    I      output table name
*  'temp_key'                    I      keyword name of the temperature
*  'count_key'                   I      keyword name of the count rate
*  'counterr_key'                I      keyword name of count rate's standard
*                                       deviation
*
*       input table column names:
*
*  (count_key)                   I      count rate, specified in 'count_key'
*  (counterr_key)                I      count rate's standard deviation,
*                                       specified in 'counterr_key'
*  (temp_key)                    I      temperature, specified in 'temp_key'
*  'APERTOBJ'                    I      aperture name
*  'PA_APER'                     I      position angle of aperture used
*  'TRGTNAME'                    I      target name
*  'EPOCH'                       I      epoch
*
*  Subroutines Called:
*  -------------------
*  CDBS:
*       CDTIN
*  SDAS:
*       UCLGSR, UCLGST, UTRGTR, UTRGTD, UTRGTT, UTTCLO, UMSPUT
*  Others:
*       None
*
*  History:
*  --------
*  Version      Date        Author          Description
*     1       07-15-86     J.-C. HSU        design and coding
*     2       10-05-87     J.-C. HSU        F77 standard
*-------------------------------------------------------------------------------
*
*== output:
*                                       --count rate and its standard deviation
        REAL                    COUNT(1), DCOUNT(1),
*                                       --temperature
     :                          TEMP(1),
*                                       --position angle of aperture used
     :                          APPA(1)
*                                       --epoch
        DOUBLE PRECISION        EPOCH(1)
*                                       --aperture name
        CHARACTER*(*)           APERT(1),
*                                       --target name
     :                          TARGET(1),
*                                       --output file name
     :                          OFILE
*                                       --total number of valid input data points
        INTEGER                 NPTS,
*                                       --error status
     :                          STATUS
*
*== local:
*                                       --number of input data points
        INTEGER                 NROWS,
*                                       --pointer of table descripter and column
*                                       --identifier
     :                          TP, COLIDN(20),
*                                       --loop indices, number of input columns
     :                          I, J, NCOLS,
*                                       --status
     :                          STAT(20), STATOK
*                                       --data buffer
        REAL                    COLBUF(20)
*                                       --column names
        CHARACTER*16            COLNAM(20)
*                                       --null flag in UTRGTR
        LOGICAL                 NULMSK(30)
        CHARACTER*5             CHAR5
*                                       --input file name
        CHARACTER*128           IFILE
*                                       --error message context
        CHARACTER*130           CONTXT, MESS
*=========================begin hsp.inc=========================================
*                                       --status return code
        INTEGER         OK, ERRNUM(20)
*                                       --message destination and priority
        INTEGER         DEST, PRIO
        DATA OK /0/
        DATA ERRNUM /701, 702, 703, 704, 705, 706, 707, 708, 709, 710,
     :               711, 712, 713, 714, 715, 716, 717, 718, 719, 720/
        DATA DEST, PRIO /5, 0/
*=========================end hsp.inc===========================================
*------------------------------------------------------------------------------
*
*  input parameters:
*
        CALL UCLGST ('intable',       IFILE, STAT(1))
        CALL UCLGST ('outtable',      OFILE, STAT(2))
        CALL UCLGST ('count_key',     COLNAM(1), STAT(3))
        CALL UCLGST ('counterr_key',  COLNAM(2), STAT(4))
        CALL UCLGST ('temp_key',      COLNAM(3), STAT(5))
*
        DO 10 I = 1, 5
            IF (STAT(I) .NE. OK) THEN
                STATUS = ERRNUM(1)
                CONTXT = 'can not get CL parameter(s)'
                GO TO 999
            END IF
   10   CONTINUE
*
*  define the rest of input column names
*
        COLNAM(4) = 'PA_APER'
        COLNAM(5) = 'EPOCH'
        COLNAM(6) = 'APERTOBJ'
        COLNAM(7) = 'TRGTNAME'
        NCOLS = 7
*
*  set up the input table
*
        CALL CDTIN (IFILE, COLNAM, NCOLS,    TP, COLIDN, NROWS, STATUS)
        IF (STATUS .NE. OK) THEN
            CONTXT = 'error setting up input table'
            GO TO 999
        END IF
*
        NPTS = 0
        DO 40 I = 1, NROWS
            CALL UTRGTR (TP, COLIDN, 4, I,      COLBUF, NULMSK, 
     :                   STAT(1))
            CALL UTRGTD (TP, COLIDN(5), 1, I,   EPOCH(I), NULMSK(5), 
     :                   STAT(2))
            CALL UTRGTT (TP, COLIDN(6), 1, I,   APERT(I), NULMSK(6), 
     :                   STAT(3))
            CALL UTRGTT (TP, COLIDN(7), 1, I,   TARGET(I), NULMSK(7), 
     :                   STAT(4))
*
            STATOK = ABS(STAT(1) - OK) + ABS(STAT(2) - OK) +
     :                  ABS(STAT(3) - OK) + ABS(STAT(4) - OK) + OK
            DO 20 J = 1, NCOLS
                IF (NULMSK(J)) THEN
                    STATOK = ERRNUM(2)
                    GO TO 30
                END IF
   20       CONTINUE
*
*  if error in UTRGT() or count rate is non-positive, put an error message and
*  do NOT increment the data array index
*
   30       CONTINUE
            IF (STATOK .NE. OK .OR. COLBUF(1) .LE. 0.) THEN
                WRITE(CHAR5, '(I5)') I
                CONTXT = 'can not read input data or non-positive '
     :                          // 'data at row #' // CHAR5
                CALL UMSPUT (CONTXT, DEST, PRIO,   STATOK)
            ELSE
                NPTS = NPTS + 1
                COUNT(NPTS) = COLBUF(1)
                DCOUNT(NPTS) = COLBUF(2)
                TEMP(NPTS) = COLBUF(3)
                APPA(NPTS) = COLBUF(4)
                EPOCH(NPTS) = EPOCH(I)
                APERT(NPTS) = APERT(I)
                TARGET(NPTS) = TARGET(I)
            END IF
   40   CONTINUE
*
*  close the input table
*
        CALL UTTCLO (TP,     STATUS)
        IF (STATUS .NE. OK) THEN
            CONTXT = 'cannot close input table'
            GO TO 999
        END IF
*
*  check if there is any valid data point
*
        IF (NPTS .LE. 0) THEN
            STATUS = ERRNUM(3)
            CONTXT = 'no valid input data'
            GO TO 999
        END IF
*
        STATUS = OK
        GO TO 1000
*
*  write error message
*
  999   MESS = 'CDPGT: ' // CONTXT
        CALL UMSPUT (MESS, DEST, PRIO,   STATOK)
*
 1000   RETURN
        END