SUBROUTINE VWRMGT (
*
*  outputs
*
     :                  ITP, ICOLID, INROWS, INCOLS, OFILE, STATUS)
*
*  Module number: 15.2.3.1
*
*  Module name: warmup
*
*  Keyphrase:
*  ----------
*  Input parameters and input table information for VWARM.
*
*  Description:
*  ------------
*
*  FORTRAN name: VWRMGT.FOR
*
*  Keywords of accessed files and tables:
*  --------------------------------------
*  Name                         I/O     Description / Comments
*  'intable'                     I      input table name
*  'outtable'                    I      output table name
*  'count_key'                   I      column name of the count rate
*  'counterr_key'                I      column name of count rate's standard dev
*  'turnon_key'                  I      column name of the most recent high
*                                       voltage turn-on time
*  'temp_key'                    I      column name of temperature
*
*       input table column names:
*
*  (count_key)                   I      count rate
*  (counterr_key)                I      count rate's standard deviation
*  (turnon_key)                  I      HV turn-on time
*  (temp_key)                    I      the temperature
*  'EPOCH'                       I      observation epoch
*  'VOLTAGE'                     I      high voltage setting
*  'APERTOBJ'                    I      aperture name
*
*  Subroutines Called:
*  -------------------
*  CDBS:
*       CDTIN
*  SDAS:
*       UCLGST, UMSPUT
*  Others:
*       None
*
*  History:
*  --------
*  Version      Date        Author          Description
*     1       06-22-87     J.-C. HSU        design and coding
*     2       11-20-87     J.-C. HSU        F77 SDAS
*-------------------------------------------------------------------------------
*
*== output:
*                                       --output file name
        CHARACTER*(*)           OFILE
*                                       --number of rows and columns of the
*                                       --input table
        INTEGER                 INROWS, INCOLS,
*                                       --pointer of table descripter and column
*                                       --identifier
     :                          ITP, ICOLID(1),
*                                       --error status
     :                          STATUS
*
*== local:
*                                       --loop indices
        INTEGER                 I,
*                                       --status
     :                          STAT(20), STATOK
*                                       --input table column names
        CHARACTER*16            ICNAME(20)
*                                       --input file name
        CHARACTER*128           IFILE
*                                       --error message context
        CHARACTER*130           CONTXT, MESS
*=========================begin hsp.inc=========================================
*                                       --status return code
        INTEGER         OK, ERRNUM(20)
*                                       --message destination and priority
        INTEGER         DEST, PRIO
        DATA OK /0/
        DATA ERRNUM /701, 702, 703, 704, 705, 706, 707, 708, 709, 710,
     :               711, 712, 713, 714, 715, 716, 717, 718, 719, 720/
        DATA DEST, PRIO /1, 0/
*=========================end hsp.inc===========================================
*------------------------------------------------------------------------------
*
*  read parameters from the parameter file
*
        CALL UCLGST ('intable',         IFILE, STAT(1))
        CALL UCLGST ('outtable',        OFILE, STAT(2))
        CALL UCLGST ('count_key',       ICNAME(1), STAT(3))
        CALL UCLGST ('counterr_key',    ICNAME(2), STAT(4))
        CALL UCLGST ('temp_key',        ICNAME(3), STAT(5))
        CALL UCLGST ('turnon_key',      ICNAME(4), STAT(6))
        DO 10 I = 1, 6
            IF (STAT(I) .NE. OK) THEN
                STATUS = ERRNUM(1)
                CONTXT = 'can not get input parameter(s)'
                GO TO 999
            END IF
   10   CONTINUE
*
*  define other column names in the input table
*
        INCOLS = 7
        ICNAME(5) = 'EPOCH'
        ICNAME(6) = 'VOLTAGE'
        ICNAME(7) = 'APERTOBJ'
*
*  set up the input table
*
        CALL CDTIN (IFILE, ICNAME, INCOLS,      ITP, ICOLID, INROWS, 
     :              STATUS)
        IF (STATUS .NE. OK) THEN
            CONTXT = 'error setting up input table'
            GO TO 999
        END IF
*
        STATUS = OK
        GO TO 1000
*
*  write error message
*
  999   MESS = 'VWRMGT: ' // CONTXT
        CALL UMSPUT (MESS, DEST, PRIO,        STATOK)
*
 1000   RETURN
        END