#  DELAYTIME -- Correct for light delay time
#
#  Description:
#  ------------
#  The high speed photometer (HSP) onboard space telescope is capable of 
#  timing observations to an accuracy of 10 millisec.  The effects of the 
#  orbital motions of the earth and the telescope on the observed
#  times may be compensated for by referring the times to the solar-system
#  barycenter.  This routine creates a file of times of observation cor-
#  rected for the light delay from three sources :  (1) general relativistic
#  effects (up to 2 millisec),  (2) the displacement of the telescope from the 
#  center of the earth (up to 20 millisec),  (3) and the displacement of the 
#  earth from the solar-system barycenter (up to 500 seconds).  
#
#  This task is capable of processing multiple files.  Since it requires user
#  inputs of target's proper motion and parallax, the input files should be for
#  the same target OR targets far away such as extragalactic objects.  The 
#  maximum time delay due to proper motions is 2.4 milliseconds per arc second
#  of position displacement and 1.2 milliseconds per arc second of parallax.
#
#  The output file of times which is created should be used as a file of
#  values of the independent variable for the data file.  This program does
#  nothing with the data themselves and makes no reference to a data mask.
#
#  It is assumed that the object under observation is well beyond the
#  solar system.  For a nearby object it would perhaps make more sense to
#  refer the times of observation to the object itself.  This should be
#  considered as a future enhancement for this program.
#
#  Date		Author			Description
#  ----		------			-----------
#  05-Nov-1984	C. D. Biemesderfer	Original module
#  18-Apr-1990  J.-C. Hsu		rewrite in SPP
#------------------------------------------------------------------------------

procedure delaytime ()

pointer	fin, fout 	# input: file template pointers
int	nfin 		# input: number of files in the input template
double	mu_ra, mu_dec	# input: proper motion of the target at J2000 (in deg.)
double	parallax	# input: parallax of the target (in arc sec)
pointer	tp_earth	# input: pointer to the earth ephemeris table
pointer	tp_obs		# input: pointer to the observer ephemeris table
#==============================================================================
begin

	# announce start of the task
	call printf ("*** DELAYTIME - Version 1.0 ***\n")

	# read input parameters
	call delaytime_get (fin, fout, nfin, mu_ra, mu_dec, parallax, 
				tp_earth, tp_obs)

	# do the delay time calculations
	call delaytime_do (fin, fout, nfin, mu_ra, mu_dec, parallax, 
				tp_earth, tp_obs)

	# close file templates
	call imtclose (fin)
	call imtclose (fout)

	# announce completion of task
	call printf ("delay time calculation task completed with no error\n")

end