include	"polarimetry.h"

#  READ_POLEFF -- read the polarizaion efficiency table
#
#  Description:
#  ------------
#  Read polarization efficiencies from an SDAS table. 
#
#  Input table column names
#  ------------------------
#
#  "APER_NAME"	 		aperture name
#  "PEFF"			polarization efficiency
#  "PEFF_ERR"			polarization efficiency's error
#
#  Input table parameters
#  ----------------------
#  (none)
#
#  Date		Author			Description
#  ----		------			-----------
#  21-Jun-1990	J.-C. Hsu		design and coding
#------------------------------------------------------------------------------

procedure read_poleff (tp_poleff, aper_poleff, poleff, poleff_err, 
			npts_poleff)

pointer	tp_poleff	# input: pointer of the polarization efficiency table
int	npts_poleff	# input: number of rows in polarization efficiency table
char	aper_poleff[SZ_APER, npts_poleff]
			# output: aperture names in the pol. efficiency table
real	poleff[npts_poleff]	
			# output: polarization efficiencies
real	poleff_err[npts_poleff]	
			# output: polarization efficiencies' errors

pointer	sp, null
pointer	colptr[10]
#==============================================================================
begin

	call smark (sp)

	# read data in the polarization efficiency table
	call salloc (null, npts_poleff, TY_BOOL)

	call tbcfnd (tp_poleff, "APER_NAME", colptr[1], 1)
	call tbcfnd (tp_poleff, "PEFF", colptr[2], 1)
	call tbcfnd (tp_poleff, "PEFF_ERR", colptr[3], 1)

	call tbcgtt (tp_poleff, colptr[1], aper_poleff, Memb[null], 
			SZ_APER, 1, npts_poleff)
	call tbcgtr (tp_poleff, colptr[2], poleff, Memb[null], 1, npts_poleff)
	call tbcgtr (tp_poleff, colptr[3], poleff_err, Memb[null], 1, 
			npts_poleff)

	call tbtclo (tp_poleff)

	call sfree (sp)

end