# Memory Management
define	SZ_TMPSTRING		SZ_COMMAND
define	Sx			Memc[sx]

#---------------------------------------------------------------------------
.help abssenz May94 source
.ih
NAME
abbsenz -- Compute absolute sensitivity table
.endhelp
#---------------------------------------------------------------------------
procedure t_abssenz()

pointer	cf_alloc()		# Open a flux object.
pointer	flux			# Input flux object.
pointer	ra_alloc()		# Open a ratio object.
pointer	ratio			# The resulting ratio.
pointer	sp			# Stack pointer.
pointer	sp_alloc()		# Open a spectrum object.
pointer	stand			# Standard star spectrum.
pointer	sx			# Temporary string.

begin
	call smark (sp)
	call salloc (sx, SZ_TMPSTRING, TY_CHAR)
	
	# Read flux table.
	call clgstr ("input", Sx, SZ_TMPSTRING)
	flux = cf_alloc ()
	call cf_read_table (flux, Sx)

	# Read the standard star table.
	call clgstr ("standard", Sx, SZ_TMPSTRING)
	stand = sp_alloc ()
	call sp_read_table (stand, Sx)

	# Open the sensitivity ratio table.
	call clgstr ("output", Sx, SZ_TMPSTRING)
	ratio = ra_alloc()

	# Compute the sensitivities.
	call abssenz (flux, stand, ratio)

	# Save the results
	call ra_write_table (ratio, Sx, NEW_FILE, NULL)

	# That's all folks.
	call ra_free (ratio)
	call sp_free (stand)
        call cf_free (flux)
	call sfree (sp)
end
#---------------------------------------------------------------------------
# End of t_abssenz
#---------------------------------------------------------------------------