! @(#)necripp.prg	17.1.1.1 (ES0-DMD) 01/25/02 17:51:11
! +++++++++++++++++++++++++++++++++++++++
!
! .IDENTIFICATION
!
!  ECHELLE PROCEDURE : ECHRIPP.PRG
!  J.D.Ponz			version 1.0 131083
!
! .PURPOSE
!
!  execute the command :
!  RIPPLE/ECHELLE INPUT OUTPUT W1,DW,K0,A0 [method]-- RIPPLE CORRECTION METHOD1
!  RIPPLE/ECHELLE INPUT OUTPUT K0,A0       -- RIPPLE CORRECTION METHOD2
! ---------------------------------------
!
DEFINE/PARAM P1 ?        IMAGE "Enter input image:"
DEFINE/PARAM P2 ?        IMAGE "Enter output image:"
DEFINE/PARAM P4 {RIPMTD} CHAR "Fitting method (SINC, OVER or FIT)"
DEFINE/PARAM P5 {RIPFRZ} CHAR "Frozen K and Alpha (YES/NO) : "
IF P4(1:1) .EQ. "S"  THEN
     DEFINE/PARAM P3 {RIPK},{ALPHA}  N
ELSE
     DEFINE/PARAM P3 {LAMBDA1},{LAMBDA2},{RIPK},{ALPHA}  N
ENDIF
WRITE/KEYW INPUTR/R/1/4 0.,0.,0.,0.
WRITE/KEYW INPUTR/R/1/4 {P3}
!
VERIFY/ECHELLE {P1} REBIN
!
IF P5(1:1) .EQ. "Y" THEN
    WRITE/OUT "Values K and Alpha will be frozen during the computation"
    WRITE/KEYW P5/C/1/1  F
ENDIF
!
DEFINE/LOCAL  METHOD/C/1/5  "YYYYY"
IF P4(1:1) .EQ. "S"  WRITE/KEYW METHOD/C/1/5  "SINC "
IF P4(1:1) .EQ. "O"  WRITE/KEYW METHOD/C/1/5  "OVER "
IF P4(1:1) .EQ. "F"  WRITE/KEYW METHOD/C/1/5  "FIT  "
IF METHOD(1:1) .EQ. "Y" THEN
   WRITE/OUT   "RIPPLE/ECHELLE: unknown method {P4}"
   RETURN/EXIT
ENDIF
WRITE/KEYW  RIPMTD/C/1/12  {METHOD}
WRITE/KEYW  RIPFRZ/C/1/3   {P5}
IF METHOD(1:1) .EQ. "S" THEN
   RIPK    = INPUTR(1)
   ALPHA   = INPUTR(2)
ELSE
   LAMBDA1 = INPUTR(1)
   LAMBDA2 = INPUTR(2)
   RIPK    = INPUTR(3)
   ALPHA   = INPUTR(4)
ENDIF
!
IF P4(1:1) .EQ. "F" THEN 
    RUN STD_EXE:NECRIPP1
ELSE
    RUN STD_EXE:NECRIPP
ENDIF