! @(#)veriall.prg	17.1.1.2 (ESO-IPG) 02/25/02 17:43:20
! ++++++++++++++++++++++++++++++++++++++++++++++++++++++
!
!  MIDAS procedure veriall.prg  to execute all the "verify" procedures
!  K. Banse     921202, 940203, 950906, 980309, 011211, 020201
!
! ++++++++++++++++++++++++++++++++++++++++++++++++++++++
! 
define/param p1 Display c "Enter NoDisplay or Display (the default):"
define/param p2 Yes c -
"Enter Yes, if automatic run (i.e. no manual input required):"
define/param p3 1 n -
"Enter flag (1/2/3/4) for using data files in Midas, FITS, M+F, F+M format):"
define/param p4 1 n "Enter no. of verification runs:"
! 
if p1(1:1) .eq. "D" then
   write/keyw dispflg/i/1/1 1
else
   write/keyw dispflg/i/1/1 0
endif
! 
if p2(1:1) .eq. "Y" then
   write/keyword alltutos/i/1/1 1
else
   write/keyword alltutos/i/1/1 0
endif
! 
write/keyw loopflag/i/1/2 1,1
write/keyw datformat/c/1/6 " " all
write/keyw times/i/1/5 0 all
times(1) = m$secs()
set/format i1
! 
do loopflag(1) = 1 {p4} 1
   loopflag(2) = {p3}			!init loopflag(2) again
   if loopflag(2) .eq. 1 .or. loopflag(2) .eq. 3 then
      datformat = "Midas "
   else
      datformat = "FITS  "
   endif
   set/midas workenv={datformat}
   write/out
   write/out *********************************************************
   write/out
   write/out    Verification run using data files in {datformat} format
   write/out
   write/out *********************************************************
   write/out
   !
   if loopflag(1) .gt. 1 @ vericopy  >Null
   !
  FITSloop:
   ! 
   @@ verify1 
   if stop .eq. 1 return/exit
   ! 
   @@ verify2 {dispflg}1111111111 111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify3 
   if stop .eq. 1 return/exit
   ! 
   @@ verify4 {dispflg}1111111111 111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify5 {dispflg}111111 1111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify6 {dispflg}1111111111 111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify7  {dispflg}1111111111 111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify8  {dispflg}1111111111 111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verifyt1 
   if stop .eq. 1 return/exit
   ! 
   @@ verifyt2 
   if stop .eq. 1 return/exit
   ! 
   @@ verifydio
   if stop .eq. 1 return/exit
   ! 
   @@ verify99  {dispflg}1111111111 111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify9  1111111111 111111111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify10  {dispflg}11111111
   if stop .eq. 1 return/exit
   ! 
   @@ verify11  {dispflg}11111111011 
   if stop .eq. 1 return/exit
   ! 
   @@ verify12  {dispflg}1111111111 
   if stop .eq. 1 return/exit
   ! 
   if loopflag(2) .gt. 2 then
      @ vericopy  >Null
      if loopflag(2) .eq. 3 then
         datformat = "FITS  "
      else
         datformat = "Midas "
      endif
      set/midas workenv={datformat}
      write/out
      write/out
      write/out *********************************************************
      write/out
      write/out    Verification run using data files in {datformat} format
      write/out
      write/out *********************************************************
      write/out
      loopflag(2) = -1			!loop only once
      goto FITSloop
   endif
enddo
! 
set/midas workenv=midas
! 
times(2) = m$secs()-times(1)
set/format i1
times(3) = times(2)/60
times(4) = times(2)-times(3)*60
write/out 
if loopflag(1) .eq. 1 then
   write/out -
   "successful end of verification run (with option {loopflag(2)})"
else
   write/out -
   "successful end of {p4} verification runs (with option {loopflag(2)})"
endif
write/out "elapsed time: {times(3)}m {times(4)}s"
!