#!/bin/tcsh -f
# PEDIT.CSH -- Startup Pedit program
#
# Eric Mandel 11/02/95
#
set noglob

# initialize SAORD variables
if ( $?SAORD_ROOT == 0 ) then
  setenv SAORD_ROOT /scisoft/saord
endif
if ( -e ${SAORD_ROOT}/xpa1 ) then
  setenv XPA_VERSION 1
else
  setenv XPA_VERSION 2
endif
if ( $?SAORD_BIN == 0 ) then
  setenv SAORD_BIN ${SAORD_ROOT}/bin.`${SAORD_ROOT}/getarch`
endif
if ( $?SAORD_TMPDIR == 0 ) then
  setenv SAORD_TMPDIR /tmp
endif
setenv SAORD_VERSION "`cat ${SAORD_ROOT}/VERSION`"
# end of SAORD initialization

# make sure we have a program
if ( $?PEDITEXE == 0 ) then
  setenv PEDITEXE ${SAORD_BIN}/Pedit
else
  echo "Using alternate Pedit program: ${PEDITEXE}"
endif
if (! -e $PEDITEXE) then
  echo "$PEDITEXE program could not be found ... exiting ..."
  exit(1)
endif

setenv PEDIT_APPDEFS	${SAORD_ROOT}/app-defaults
if ($?XFILESEARCHPATH == 0) then
    setenv XFILESEARCHPATH "${PEDIT_APPDEFS}/%N%S"
else
    setenv XFILESEARCHPATH "${XFILESEARCHPATH}:${PEDIT_APPDEFS}/%N%S"
endif
if ($?XAPPLRESDIR == 0) then
    setenv XAPPLRESDIR "${PEDIT_APPDEFS}"
else
  if ( ! -e ${XAPPLRESDIR}/ParamEdit ) then
    setenv XAPPLRESDIR "${PEDIT_APPDEFS}"
  endif
endif

${PEDITEXE} $*